/ #CouchDB #Erlang 

eCloudEdit Part 2: CouchDB

In my last post I showed the Webmachine backend to James Yu’s CloudEdit app in Backbone.js. What was left out was, where are the documents stored? Here I’ll show how this is done with CouchDB. And you can give the app a try at http://erlware.org:8080

First, a new Erlang app is needed that we’ll call ece_db.

  
ece_db/  
├── doc  
├── ebin  
│   ├── ece_db.app  
│   └── overview.edoc  
├── include  
└── src  
    ├── ece_db.erl  
    ├── ece_db_app.erl  
    └── ece_db_sup.erl

Three modules are implemented, one that starts the app by calling the supervisor’s start function, the supervisor itself that sets up a _simple_one_forone and the _genserver that handles the frontends requests for creating and modifying documents in CouchDB.

We’ll ignore the _ece_dbapp.erl module for this post and start with _ece_dbsup.erl. On requests from the Webmachine resource module we don’t want one to wait on the other, requests should be handled in parrallel. One option is to not create a process for the database backend and instead have all of the functions in the database interface run in the process of the Webmachine resource. However, two reasons to not do this are that there are multiple pieces of data that must be read out of a configuration file and used to setup what is needed to talk to CouchDB. We do not want to be doing this for every request! Furthermore a supervised _genserver allows us the possibility of retrying requests with no extra code and crashing without retrying but not taking down the resource’s process that is handling the user’s HTTP request. It is a lot nicer and easier to just let things fail when we can!

  
  {ece_db, [{server, "HOSTNAME"},  
            {port, 80},  
            {database, "ecloudedit"}]}
  
-spec init(list()) -> {ok, {SupFlags::any(), [ChildSpec::any()]}} |  
                       ignore | {error, Reason::any()}.  
init([]) ->  
    RestartStrategy = simple_one_for_one,  
    MaxRestarts = 0,  
    MaxSecondsBetweenRestarts = 1,  
  
    SupFlags = {RestartStrategy, MaxRestarts, MaxSecondsBetweenRestarts},  
  
    Restart = temporary,  
    Shutdown = 2000,  
    Type = worker,  
  
    {ok, Server} = application:get_env(server),  
    {ok, Port} = application:get_env(port),  
    {ok, DB} = application:get_env(database),  
  
    AChild = {ece_db, {ece_db, start_link, [Server, Port, DB]},  
              Restart, Shutdown, Type, [ece_db]},  
  
    {ok, {SupFlags, [AChild]}}.

First, we have the config entries in config/sys.config that will be read in by _application:genenv. Here we set the server URL, port number and name of the database to use. CouchDB can easily be run locally but for my running copy I use a database hosted by the great service Cloudant. Next is the init function for _ece_dbsup.erl. A key thing to note for a _simple_one_forone is that NO process is started after the supervisor’s init function returns like with other types of supervisor children. Instead we must explicitly call _startchild. This is how we are able to create a supervised _genserver process for every HTTP request. Below is the code in _ece_dbsup for starting and stopping the process:

  
start_child() ->  
    supervisor:start_child(?SERVER, []).  
  
terminate_child(PID) ->  
    ece_db:terminate_child(PID).

In the last post I showed the functions that start and stop the _ecedb process. Here they are again:

  
init([]) ->  
    {ok, PID} = ece_db_sup:start_child(),  
    {ok, #ctx{db=PID}}.
  
finish_request(ReqData, Ctx) ->  
    ece_db_sup:terminate_child(Ctx#ctx.db),  
    {true, ReqData, Ctx}.

On each request Webmachine calls the init function for the resource that is matched in the dispatch table. In that init function we call _startchild in _ece_dbsup which returns {ok, PID}. The PID is the process id we’ll be sending messages. Now in _ecedb we implement the API functions needed to start the process and to interact with it.

  
start_link(Server, Port, DB) ->  
    gen_server:start_link(?MODULE, [Server, Port, DB], []).  
  
all(PID) ->  
    gen_server:call(PID, all).  
  
find(PID, ID) ->  
    gen_server:call(PID, {find, ID}).  
  
create(PID, Doc) ->  
    gen_server:call(PID, {create, Doc}).  
  
update(PID, ID, JsonDoc) ->  
    gen_server:call(PID, {update, ID, JsonDoc}).  
  
terminate(PID) ->  
    gen_server:call(PID, terminate).  

Each function, besides the one for starting the process, takes a PID. This PID is the process _genserver:call to which it sends its message. To handle these messages we have the _genserver callbacks.

  
%%%===================================================================  
%%% gen_server callbacks  
%%%===================================================================  
  
%% @private  
init([Server, Port, DB]) ->  
    CouchServer = couchbeam:server_connection(Server, Port, "", []),  
    {ok, CouchDB} = couchbeam:open_db(CouchServer, DB),  
    {ok, #state{db=CouchDB}}.  
  
%% @private  
handle_call(all, _From, #state{db=DB}=State) ->  
    Docs = get_docs(DB, [{descending, true}]),  
    {reply, mochijson2:encode(Docs), State};  
handle_call({find, ID}, _From, #state{db=DB}=State) ->  
    [Doc] = get_docs(DB, [{key, list_to_binary(ID)}]),  
    {reply, mochijson2:encode(Doc), State};  
handle_call({create, Doc}, _From, #state{db=DB}=State) ->  
    {ok, Doc1} = couchbeam:save_doc(DB, Doc),  
    {NewDoc} = couchbeam_doc:set_value(<<"id">>, couchbeam_doc:get_id(Doc1), Doc1),  
    {reply, mochijson2:encode(NewDoc), State};  
handle_call({update, ID, NewDoc}, _From, #state{db=DB}=State) ->  
    IDBinary = list_to_binary(ID),  
    {ok, Doc} = couchbeam:open_doc(DB, IDBinary),  
    NewDoc2 = couchbeam_doc:set_value(<<"_id">>, IDBinary, {NewDoc}),  
    NewDoc3 = couchbeam_doc:set_value(<<"_rev">>, couchbeam_doc:get_rev(Doc), NewDoc2),  
    {ok, {Doc1}} = couchbeam:save_doc(DB, NewDoc3),  
    {reply, mochijson2:encode(Doc1), State;  
handle_call(terminate, _From, State) ->  
    {stop, normal, State}.

init takes the server URL, the port number and the name of the database to store the documents as arguments and creates a CouchBeam database record. To handle the other messages we have the _handlecall function to match on the different tuples sent to _genserver:call for the different function calls. all uses the internal function _getdocs with the option to have the function in descending order (so the newest is first) and returns those after encoding to JSON. find uses the same function but only wants a certain document which in the case of CouchDB is specified with a key value. create first saves the new document which returns the document that is actually stored in CouchDB. CouchDB adds the _id and _rev key/value pairs it generates. Since our frontend expects the id to be the value of a key id and not _id we use _couchbeam_doc:setvalue to set a value of the new key id with the value of the documents id retrieved from the document with _couchbeam_doc:getid. For update we first open the document corresponding to the id passed in as an argument to get the _rev value. _rev needs to be set in the document we send to _savedoc so CouchDB knows this is a valid update based on the previous version of the document. Thus we set the new documents _id and _rev values and send to _savedoc.

Lastly, we have the _getdocs function. Since the frontend expects the key id to exist and CouchDB stores the id with the key _id we use a simple view to return the documents with id containing the value of the documents _id. Views are defined with map/reduce functions that CouchDB runs across the databases documents and builds an index from. These indexes are then queried based on keys to find documents. Thus access is very quick, indexes are built with BTrees, and a map/reduce does not have to be run on the documents for every request. Additionally, when a new document is created the view’s map/reduce functions only need to run over the new documents to update the BTree. Updates to the view’s indexes are either done on each use of the view or can be manually told to run.

  
function (doc)  
{  
  emit(doc._id, {id : doc._id, title : doc.title, created_at : doc.created_at, body : doc.body});  
}
  
get_docs(DB, Options) ->  
    {ok, AllDocs} = couchbeam:view(DB, {"all", "find"}, Options),  
    {ok, Results} = couchbeam_view:fetch(AllDocs),  
  
    {[{<<"total_rows">>, _Total},  
      {<<"offset">>, _Offset},  
      {<<"rows">>, Rows}]} = Results,  
  
    lists:map(fun({Row}) ->  
                      {<<"value">>, {Value}} = lists:keyfind(<<"value">>, 1, Row),  
                      Value  
              end, Rows).  

In _getdocs the couchbeam:view function is used to construct a view request to be sent to the CouchDB server. _couchbeamview:fetch sends the view request and returns the results as Erlang terms. After this we extract the rows from the results and use lists:map to extract out just the value of each row to be returned.

That’s it! There are places that could use improvement. One being the use of lists:map over every returned row to construct documents the frontend can deal with. Additionally, the need to duplicate _id as id for the frontends use could be removed through modifications on the frontend.

In the next installment I’ll be updating the code – and maybe making some of these performance enhancements – with James Yu’s recent changes in his Part 2.